@ECHO OFF

SET D1=%1
SET D2=%2
IF "%D1%"=="" SET D1=%WINDIR%
IF "%D2%"=="" SET D2=%WINBOOTDIR%
IF "%D2%"=="" SET D2=%D1%
IF "%D1%"=="" GOTO NOARG

IF NOT EXIST %D1%\SMARTDRV.EXE GOTO BADPATH
ATTRIB.EXE -S -H -R C:\IO.SYS

IF NOT EXIST %D2%\DBLBUFF.SYS GOTO WIN98

IF NOT EXIST C:\IO.BAK GOTO INST
IF NOT EXIST %D2%\DBLBUFF.BAK GOTO INST
IF NOT EXIST %D1%\SMARTDRV.BAK GOTO INST

IF NOT EXIST C:\IO.SYS GOTO MISSING
IF NOT EXIST %D1%\SMARTDRV.EXE GOTO MISSING

DEL C:\IO.SYS
DEL %D2%\DBLBUFF.SYS
DEL %D1%\SMARTDRV.EXE

REN C:\IO.BAK IO.SYS
REN %D2%\DBLBUFF.BAK DBLBUFF.SYS
REN %D1%\SMARTDRV.BAK SMARTDRV.EXE

ECHO TBPLUS DOS PATCHES REMOVED SUCCESSFULLY
GOTO EXIT

:INST
IF EXIST C:\IO.BAK GOTO MOD
IF EXIST %D2%\DBLBUFF.BAK GOTO MOD
IF EXIST %D1%\SMARTDRV.BAK GOTO MOD
ECHO TBPLUS DOS PATCHES NOT APPLIED - RUN INSTALLD TO INSTALL
GOTO EXIT
:MOD
ECHO ONE OR MORE FILES NOT PATCHED - UNINSTALL MANUALLY
GOTO EXIT
:WIN98
IF NOT "%2"=="" GOTO MISSING
ECHO WINDOWS BOOT DIRECTORY PATH MUST ALSO BE SPECIFIED FOR WINDOWS 98
GOTO EXIT
:MISSING
ECHO FILES MISSING OR WINDOWS DAMAGED
GOTO EXIT
:BADPATH
ECHO WINDOWS PATH INCORRECT OR WINDOWS DAMAGED
GOTO EXIT
:NOARG
ECHO WINDOWS DIRECTORY PATH MUST BE SPECIFIED
:EXIT
@ECHO ON